home *** CD-ROM | disk | FTP | other *** search
/ Skunkware 98 / Skunkware 98.iso / src / interp / perl5.005.tar.gz / perl5.005.tar / perl5.005 / pod / perlsyn.pod < prev    next >
Text File  |  1998-07-20  |  22KB  |  618 lines
  1. =head1 NAME
  2.  
  3. perlsyn - Perl syntax
  4.  
  5. =head1 DESCRIPTION
  6.  
  7. A Perl script consists of a sequence of declarations and statements.
  8. The only things that need to be declared in Perl are report formats
  9. and subroutines.  See the sections below for more information on those
  10. declarations.  All uninitialized user-created objects are assumed to
  11. start with a C<null> or C<0> value until they are defined by some explicit
  12. operation such as assignment.  (Though you can get warnings about the
  13. use of undefined values if you like.)  The sequence of statements is
  14. executed just once, unlike in B<sed> and B<awk> scripts, where the
  15. sequence of statements is executed for each input line.  While this means
  16. that you must explicitly loop over the lines of your input file (or
  17. files), it also means you have much more control over which files and
  18. which lines you look at.  (Actually, I'm lying--it is possible to do an
  19. implicit loop with either the B<-n> or B<-p> switch.  It's just not the
  20. mandatory default like it is in B<sed> and B<awk>.)
  21.  
  22. =head2 Declarations
  23.  
  24. Perl is, for the most part, a free-form language.  (The only
  25. exception to this is format declarations, for obvious reasons.) Comments
  26. are indicated by the C<"#"> character, and extend to the end of the line.  If
  27. you attempt to use C</* */> C-style comments, it will be interpreted
  28. either as division or pattern matching, depending on the context, and C++
  29. C<//> comments just look like a null regular expression, so don't do
  30. that.
  31.  
  32. A declaration can be put anywhere a statement can, but has no effect on
  33. the execution of the primary sequence of statements--declarations all
  34. take effect at compile time.  Typically all the declarations are put at
  35. the beginning or the end of the script.  However, if you're using
  36. lexically-scoped private variables created with C<my()>, you'll have to make sure
  37. your format or subroutine definition is within the same block scope
  38. as the my if you expect to be able to access those private variables.
  39.  
  40. Declaring a subroutine allows a subroutine name to be used as if it were a
  41. list operator from that point forward in the program.  You can declare a
  42. subroutine without defining it by saying C<sub name>, thus:
  43.  
  44.     sub myname;
  45.     $me = myname $0         or die "can't get myname";
  46.  
  47. Note that it functions as a list operator, not as a unary operator; so
  48. be careful to use C<or> instead of C<||> in this case.  However, if
  49. you were to declare the subroutine as C<sub myname ($)>, then
  50. C<myname> would function as a unary operator, so either C<or> or
  51. C<||> would work.
  52.  
  53. Subroutines declarations can also be loaded up with the C<require> statement
  54. or both loaded and imported into your namespace with a C<use> statement.
  55. See L<perlmod> for details on this.
  56.  
  57. A statement sequence may contain declarations of lexically-scoped
  58. variables, but apart from declaring a variable name, the declaration acts
  59. like an ordinary statement, and is elaborated within the sequence of
  60. statements as if it were an ordinary statement.  That means it actually
  61. has both compile-time and run-time effects.
  62.  
  63. =head2 Simple statements
  64.  
  65. The only kind of simple statement is an expression evaluated for its
  66. side effects.  Every simple statement must be terminated with a
  67. semicolon, unless it is the final statement in a block, in which case
  68. the semicolon is optional.  (A semicolon is still encouraged there if the
  69. block takes up more than one line, because you may eventually add another line.)
  70. Note that there are some operators like C<eval {}> and C<do {}> that look
  71. like compound statements, but aren't (they're just TERMs in an expression),
  72. and thus need an explicit termination if used as the last item in a statement.
  73.  
  74. Any simple statement may optionally be followed by a I<SINGLE> modifier,
  75. just before the terminating semicolon (or block ending).  The possible
  76. modifiers are:
  77.  
  78.     if EXPR
  79.     unless EXPR
  80.     while EXPR
  81.     until EXPR
  82.     foreach EXPR
  83.  
  84. The C<if> and C<unless> modifiers have the expected semantics,
  85. presuming you're a speaker of English.  The C<foreach> modifier is an
  86. iterator:  For each value in EXPR, it aliases C<$_> to the value and
  87. executes the statement.  The C<while> and C<until> modifiers have the
  88. usual "C<while> loop" semantics (conditional evaluated first), except
  89. when applied to a C<do>-BLOCK (or to the now-deprecated C<do>-SUBROUTINE
  90. statement), in which case the block executes once before the
  91. conditional is evaluated.  This is so that you can write loops like:
  92.  
  93.     do {
  94.     $line = <STDIN>;
  95.     ...
  96.     } until $line  eq ".\n";
  97.  
  98. See L<perlfunc/do>.  Note also that the loop control statements described
  99. later will I<NOT> work in this construct, because modifiers don't take
  100. loop labels.  Sorry.  You can always put another block inside of it
  101. (for C<next>) or around it (for C<last>) to do that sort of thing.
  102. For C<next>, just double the braces:
  103.  
  104.     do {{
  105.     next if $x == $y;
  106.     # do something here
  107.     }} until $x++ > $z;
  108.  
  109. For C<last>, you have to be more elaborate:
  110.  
  111.     LOOP: { 
  112.         do {
  113.         last if $x = $y**2;
  114.         # do something here
  115.         } while $x++ <= $z;
  116.     }
  117.  
  118. =head2 Compound statements
  119.  
  120. In Perl, a sequence of statements that defines a scope is called a block.
  121. Sometimes a block is delimited by the file containing it (in the case
  122. of a required file, or the program as a whole), and sometimes a block
  123. is delimited by the extent of a string (in the case of an eval).
  124.  
  125. But generally, a block is delimited by curly brackets, also known as braces.
  126. We will call this syntactic construct a BLOCK.
  127.  
  128. The following compound statements may be used to control flow:
  129.  
  130.     if (EXPR) BLOCK
  131.     if (EXPR) BLOCK else BLOCK
  132.     if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
  133.     LABEL while (EXPR) BLOCK
  134.     LABEL while (EXPR) BLOCK continue BLOCK
  135.     LABEL for (EXPR; EXPR; EXPR) BLOCK
  136.     LABEL foreach VAR (LIST) BLOCK
  137.     LABEL BLOCK continue BLOCK
  138.  
  139. Note that, unlike C and Pascal, these are defined in terms of BLOCKs,
  140. not statements.  This means that the curly brackets are I<required>--no
  141. dangling statements allowed.  If you want to write conditionals without
  142. curly brackets there are several other ways to do it.  The following
  143. all do the same thing:
  144.  
  145.     if (!open(FOO)) { die "Can't open $FOO: $!"; }
  146.     die "Can't open $FOO: $!" unless open(FOO);
  147.     open(FOO) or die "Can't open $FOO: $!";    # FOO or bust!
  148.     open(FOO) ? 'hi mom' : die "Can't open $FOO: $!";
  149.             # a bit exotic, that last one
  150.  
  151. The C<if> statement is straightforward.  Because BLOCKs are always
  152. bounded by curly brackets, there is never any ambiguity about which
  153. C<if> an C<else> goes with.  If you use C<unless> in place of C<if>,
  154. the sense of the test is reversed.
  155.  
  156. The C<while> statement executes the block as long as the expression is
  157. true (does not evaluate to the null string (C<"">) or C<0> or C<"0")>.  The LABEL is
  158. optional, and if present, consists of an identifier followed by a colon.
  159. The LABEL identifies the loop for the loop control statements C<next>,
  160. C<last>, and C<redo>.  If the LABEL is omitted, the loop control statement
  161. refers to the innermost enclosing loop.  This may include dynamically
  162. looking back your call-stack at run time to find the LABEL.  Such
  163. desperate behavior triggers a warning if you use the B<-w> flag.
  164.  
  165. If there is a C<continue> BLOCK, it is always executed just before the
  166. conditional is about to be evaluated again, just like the third part of a
  167. C<for> loop in C.  Thus it can be used to increment a loop variable, even
  168. when the loop has been continued via the C<next> statement (which is
  169. similar to the C C<continue> statement).
  170.  
  171. =head2 Loop Control
  172.  
  173. The C<next> command is like the C<continue> statement in C; it starts
  174. the next iteration of the loop:
  175.  
  176.     LINE: while (<STDIN>) {
  177.     next LINE if /^#/;    # discard comments
  178.     ...
  179.     }
  180.  
  181. The C<last> command is like the C<break> statement in C (as used in
  182. loops); it immediately exits the loop in question.  The
  183. C<continue> block, if any, is not executed:
  184.  
  185.     LINE: while (<STDIN>) {
  186.     last LINE if /^$/;    # exit when done with header
  187.     ...
  188.     }
  189.  
  190. The C<redo> command restarts the loop block without evaluating the
  191. conditional again.  The C<continue> block, if any, is I<not> executed.
  192. This command is normally used by programs that want to lie to themselves
  193. about what was just input.
  194.  
  195. For example, when processing a file like F</etc/termcap>.
  196. If your input lines might end in backslashes to indicate continuation, you
  197. want to skip ahead and get the next record.
  198.  
  199.     while (<>) {
  200.     chomp;
  201.     if (s/\\$//) {
  202.         $_ .= <>;
  203.         redo unless eof();
  204.     }
  205.     # now process $_
  206.     }
  207.  
  208. which is Perl short-hand for the more explicitly written version:
  209.  
  210.     LINE: while (defined($line = <ARGV>)) {
  211.     chomp($line);
  212.     if ($line =~ s/\\$//) {
  213.         $line .= <ARGV>;
  214.         redo LINE unless eof(); # not eof(ARGV)!
  215.     }
  216.     # now process $line
  217.     }
  218.  
  219. Note that if there were a C<continue> block on the above code, it would get
  220. executed even on discarded lines.  This is often used to reset line counters 
  221. or C<?pat?> one-time matches.
  222.  
  223.     # inspired by :1,$g/fred/s//WILMA/
  224.     while (<>) {
  225.     ?(fred)?    && s//WILMA $1 WILMA/;
  226.     ?(barney)?  && s//BETTY $1 BETTY/;
  227.     ?(homer)?   && s//MARGE $1 MARGE/;
  228.     } continue {
  229.     print "$ARGV $.: $_";
  230.     close ARGV  if eof();        # reset $.
  231.     reset        if eof();        # reset ?pat?
  232.     }
  233.  
  234. If the word C<while> is replaced by the word C<until>, the sense of the
  235. test is reversed, but the conditional is still tested before the first
  236. iteration.
  237.  
  238. The loop control statements don't work in an C<if> or C<unless>, since
  239. they aren't loops.  You can double the braces to make them such, though.
  240.  
  241.     if (/pattern/) {{
  242.     next if /fred/;
  243.     next if /barney/;
  244.     # so something here
  245.     }}
  246.  
  247. The form C<while/if BLOCK BLOCK>, available in Perl 4, is no longer
  248. available.   Replace any occurrence of C<if BLOCK> by C<if (do BLOCK)>.
  249.  
  250. =head2 For Loops
  251.  
  252. Perl's C-style C<for> loop works exactly like the corresponding C<while> loop;
  253. that means that this:
  254.  
  255.     for ($i = 1; $i < 10; $i++) {
  256.     ...
  257.     }
  258.  
  259. is the same as this:
  260.  
  261.     $i = 1;
  262.     while ($i < 10) {
  263.     ...
  264.     } continue {
  265.     $i++;
  266.     }
  267.  
  268. (There is one minor difference: The first form implies a lexical scope
  269. for variables declared with C<my> in the initialization expression.)
  270.  
  271. Besides the normal array index looping, C<for> can lend itself
  272. to many other interesting applications.  Here's one that avoids the
  273. problem you get into if you explicitly test for end-of-file on
  274. an interactive file descriptor causing your program to appear to
  275. hang.
  276.  
  277.     $on_a_tty = -t STDIN && -t STDOUT;
  278.     sub prompt { print "yes? " if $on_a_tty }
  279.     for ( prompt(); <STDIN>; prompt() ) {
  280.     # do something
  281.     }
  282.  
  283. =head2 Foreach Loops
  284.  
  285. The C<foreach> loop iterates over a normal list value and sets the
  286. variable VAR to be each element of the list in turn.  If the variable
  287. is preceded with the keyword C<my>, then it is lexically scoped, and
  288. is therefore visible only within the loop.  Otherwise, the variable is
  289. implicitly local to the loop and regains its former value upon exiting
  290. the loop.  If the variable was previously declared with C<my>, it uses
  291. that variable instead of the global one, but it's still localized to
  292. the loop.  (Note that a lexically scoped variable can cause problems
  293. if you have subroutine or format declarations within the loop which
  294. refer to it.)
  295.  
  296. The C<foreach> keyword is actually a synonym for the C<for> keyword, so
  297. you can use C<foreach> for readability or C<for> for brevity.  (Or because
  298. the Bourne shell is more familiar to you than I<csh>, so writing C<for>
  299. comes more naturally.)  If VAR is omitted, C<$_> is set to each value.
  300. If any element of LIST is an lvalue, you can modify it by modifying VAR
  301. inside the loop.  That's because the C<foreach> loop index variable is
  302. an implicit alias for each item in the list that you're looping over.
  303.  
  304. If any part of LIST is an array, C<foreach> will get very confused if
  305. you add or remove elements within the loop body, for example with
  306. C<splice>.   So don't do that.
  307.  
  308. C<foreach> probably won't do what you expect if VAR is a tied or other
  309. special variable.   Don't do that either.
  310.  
  311. Examples:
  312.  
  313.     for (@ary) { s/foo/bar/ }
  314.  
  315.     foreach my $elem (@elements) {
  316.     $elem *= 2;
  317.     }
  318.  
  319.     for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') {
  320.     print $count, "\n"; sleep(1);
  321.     }
  322.  
  323.     for (1..15) { print "Merry Christmas\n"; }
  324.  
  325.     foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
  326.     print "Item: $item\n";
  327.     }
  328.  
  329. Here's how a C programmer might code up a particular algorithm in Perl:
  330.  
  331.     for (my $i = 0; $i < @ary1; $i++) {
  332.     for (my $j = 0; $j < @ary2; $j++) {
  333.         if ($ary1[$i] > $ary2[$j]) {
  334.         last; # can't go to outer :-(
  335.         }
  336.         $ary1[$i] += $ary2[$j];
  337.     }
  338.     # this is where that last takes me
  339.     }
  340.  
  341. Whereas here's how a Perl programmer more comfortable with the idiom might
  342. do it:
  343.  
  344.     OUTER: foreach my $wid (@ary1) {
  345.     INNER:   foreach my $jet (@ary2) {
  346.         next OUTER if $wid > $jet;
  347.         $wid += $jet;
  348.          }
  349.       }
  350.  
  351. See how much easier this is?  It's cleaner, safer, and faster.  It's
  352. cleaner because it's less noisy.  It's safer because if code gets added
  353. between the inner and outer loops later on, the new code won't be
  354. accidentally executed.  The C<next> explicitly iterates the other loop
  355. rather than merely terminating the inner one.  And it's faster because
  356. Perl executes a C<foreach> statement more rapidly than it would the
  357. equivalent C<for> loop.
  358.  
  359. =head2 Basic BLOCKs and Switch Statements
  360.  
  361. A BLOCK by itself (labeled or not) is semantically equivalent to a
  362. loop that executes once.  Thus you can use any of the loop control
  363. statements in it to leave or restart the block.  (Note that this is
  364. I<NOT> true in C<eval{}>, C<sub{}>, or contrary to popular belief
  365. C<do{}> blocks, which do I<NOT> count as loops.)  The C<continue>
  366. block is optional.
  367.  
  368. The BLOCK construct is particularly nice for doing case
  369. structures.
  370.  
  371.     SWITCH: {
  372.     if (/^abc/) { $abc = 1; last SWITCH; }
  373.     if (/^def/) { $def = 1; last SWITCH; }
  374.     if (/^xyz/) { $xyz = 1; last SWITCH; }
  375.     $nothing = 1;
  376.     }
  377.  
  378. There is no official C<switch> statement in Perl, because there are
  379. already several ways to write the equivalent.  In addition to the
  380. above, you could write
  381.  
  382.     SWITCH: {
  383.     $abc = 1, last SWITCH  if /^abc/;
  384.     $def = 1, last SWITCH  if /^def/;
  385.     $xyz = 1, last SWITCH  if /^xyz/;
  386.     $nothing = 1;
  387.     }
  388.  
  389. (That's actually not as strange as it looks once you realize that you can
  390. use loop control "operators" within an expression,  That's just the normal
  391. C comma operator.)
  392.  
  393. or
  394.  
  395.     SWITCH: {
  396.     /^abc/ && do { $abc = 1; last SWITCH; };
  397.     /^def/ && do { $def = 1; last SWITCH; };
  398.     /^xyz/ && do { $xyz = 1; last SWITCH; };
  399.     $nothing = 1;
  400.     }
  401.  
  402. or formatted so it stands out more as a "proper" C<switch> statement:
  403.  
  404.     SWITCH: {
  405.     /^abc/         && do {
  406.                 $abc = 1;
  407.                 last SWITCH;
  408.                };
  409.  
  410.     /^def/         && do {
  411.                 $def = 1;
  412.                 last SWITCH;
  413.                };
  414.  
  415.     /^xyz/         && do {
  416.                 $xyz = 1;
  417.                 last SWITCH;
  418.                 };
  419.     $nothing = 1;
  420.     }
  421.  
  422. or
  423.  
  424.     SWITCH: {
  425.     /^abc/ and $abc = 1, last SWITCH;
  426.     /^def/ and $def = 1, last SWITCH;
  427.     /^xyz/ and $xyz = 1, last SWITCH;
  428.     $nothing = 1;
  429.     }
  430.  
  431. or even, horrors,
  432.  
  433.     if (/^abc/)
  434.     { $abc = 1 }
  435.     elsif (/^def/)
  436.     { $def = 1 }
  437.     elsif (/^xyz/)
  438.     { $xyz = 1 }
  439.     else
  440.     { $nothing = 1 }
  441.  
  442. A common idiom for a C<switch> statement is to use C<foreach>'s aliasing to make
  443. a temporary assignment to C<$_> for convenient matching:
  444.  
  445.     SWITCH: for ($where) {
  446.         /In Card Names/     && do { push @flags, '-e'; last; };
  447.         /Anywhere/          && do { push @flags, '-h'; last; };
  448.         /In Rulings/        && do {                    last; };
  449.         die "unknown value for form variable where: `$where'";
  450.         }
  451.  
  452. Another interesting approach to a switch statement is arrange
  453. for a C<do> block to return the proper value:
  454.  
  455.     $amode = do {
  456.     if     ($flag & O_RDONLY) { "r" }    # XXX: isn't this 0?
  457.     elsif  ($flag & O_WRONLY) { ($flag & O_APPEND) ? "a" : "w" }
  458.     elsif  ($flag & O_RDWR)   {
  459.         if ($flag & O_CREAT)  { "w+" }
  460.         else                  { ($flag & O_APPEND) ? "a+" : "r+" }
  461.     }
  462.     };
  463.  
  464. Or 
  465.  
  466.         print do {
  467.             ($flags & O_WRONLY) ? "write-only"          :
  468.             ($flags & O_RDWR)   ? "read-write"          :
  469.                                   "read-only";
  470.         };
  471.  
  472. Or if you are certainly that all the C<&&> clauses are true, you can use
  473. something like this, which "switches" on the value of the
  474. C<HTTP_USER_AGENT> envariable.
  475.  
  476.     #!/usr/bin/perl 
  477.     # pick out jargon file page based on browser
  478.     $dir = 'http://www.wins.uva.nl/~mes/jargon';
  479.     for ($ENV{HTTP_USER_AGENT}) { 
  480.     $page  =    /Mac/            && 'm/Macintrash.html'
  481.          || /Win(dows )?NT/  && 'e/evilandrude.html'
  482.          || /Win|MSIE|WebTV/ && 'm/MicroslothWindows.html'
  483.          || /Linux/          && 'l/Linux.html'
  484.          || /HP-UX/          && 'h/HP-SUX.html'
  485.          || /SunOS/          && 's/ScumOS.html'
  486.          ||                     'a/AppendixB.html';
  487.     }
  488.     print "Location: $dir/$page\015\012\015\012";
  489.  
  490. That kind of switch statement only works when you know the C<&&> clauses
  491. will be true.  If you don't, the previous C<?:> example should be used.
  492.  
  493. You might also consider writing a hash instead of synthesizing a C<switch>
  494. statement.
  495.  
  496. =head2 Goto
  497.  
  498. Although not for the faint of heart, Perl does support a C<goto> statement.
  499. A loop's LABEL is not actually a valid target for a C<goto>;
  500. it's just the name of the loop.  There are three forms: C<goto>-LABEL,
  501. C<goto>-EXPR, and C<goto>-&NAME.
  502.  
  503. The C<goto>-LABEL form finds the statement labeled with LABEL and resumes
  504. execution there.  It may not be used to go into any construct that
  505. requires initialization, such as a subroutine or a C<foreach> loop.  It
  506. also can't be used to go into a construct that is optimized away.  It
  507. can be used to go almost anywhere else within the dynamic scope,
  508. including out of subroutines, but it's usually better to use some other
  509. construct such as C<last> or C<die>.  The author of Perl has never felt the
  510. need to use this form of C<goto> (in Perl, that is--C is another matter).
  511.  
  512. The C<goto>-EXPR form expects a label name, whose scope will be resolved
  513. dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
  514. necessarily recommended if you're optimizing for maintainability:
  515.  
  516.     goto ("FOO", "BAR", "GLARCH")[$i];
  517.  
  518. The C<goto>-&NAME form is highly magical, and substitutes a call to the
  519. named subroutine for the currently running subroutine.  This is used by
  520. C<AUTOLOAD()> subroutines that wish to load another subroutine and then
  521. pretend that the other subroutine had been called in the first place
  522. (except that any modifications to C<@_> in the current subroutine are
  523. propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
  524. will be able to tell that this routine was called first.
  525.  
  526. In almost all cases like this, it's usually a far, far better idea to use the
  527. structured control flow mechanisms of C<next>, C<last>, or C<redo> instead of
  528. resorting to a C<goto>.  For certain applications, the catch and throw pair of
  529. C<eval{}> and die() for exception processing can also be a prudent approach.
  530.  
  531. =head2 PODs: Embedded Documentation
  532.  
  533. Perl has a mechanism for intermixing documentation with source code.
  534. While it's expecting the beginning of a new statement, if the compiler
  535. encounters a line that begins with an equal sign and a word, like this
  536.  
  537.     =head1 Here There Be Pods!
  538.  
  539. Then that text and all remaining text up through and including a line
  540. beginning with C<=cut> will be ignored.  The format of the intervening
  541. text is described in L<perlpod>.
  542.  
  543. This allows you to intermix your source code
  544. and your documentation text freely, as in
  545.  
  546.     =item snazzle($)
  547.  
  548.     The snazzle() function will behave in the most spectacular
  549.     form that you can possibly imagine, not even excepting
  550.     cybernetic pyrotechnics.
  551.  
  552.     =cut back to the compiler, nuff of this pod stuff!
  553.  
  554.     sub snazzle($) {
  555.     my $thingie = shift;
  556.     .........
  557.     }
  558.  
  559. Note that pod translators should look at only paragraphs beginning
  560. with a pod directive (it makes parsing easier), whereas the compiler
  561. actually knows to look for pod escapes even in the middle of a
  562. paragraph.  This means that the following secret stuff will be
  563. ignored by both the compiler and the translators.
  564.  
  565.     $a=3;
  566.     =secret stuff
  567.      warn "Neither POD nor CODE!?"
  568.     =cut back
  569.     print "got $a\n";
  570.  
  571. You probably shouldn't rely upon the C<warn()> being podded out forever.
  572. Not all pod translators are well-behaved in this regard, and perhaps
  573. the compiler will become pickier.
  574.  
  575. One may also use pod directives to quickly comment out a section
  576. of code.
  577.  
  578. =head2 Plain Old Comments (Not!)
  579.  
  580. Much like the C preprocessor, Perl can process line directives.  Using
  581. this, one can control Perl's idea of filenames and line numbers in
  582. error or warning messages (especially for strings that are processed
  583. with C<eval()>).  The syntax for this mechanism is the same as for most
  584. C preprocessors: it matches the regular expression
  585. C</^#\s*line\s+(\d+)\s*(?:\s"([^"]*)")?/> with C<$1> being the line
  586. number for the next line, and C<$2> being the optional filename
  587. (specified within quotes).
  588.  
  589. Here are some examples that you should be able to type into your command
  590. shell:
  591.  
  592.     % perl
  593.     # line 200 "bzzzt"
  594.     # the `#' on the previous line must be the first char on line
  595.     die 'foo';
  596.     __END__
  597.     foo at bzzzt line 201.
  598.  
  599.     % perl
  600.     # line 200 "bzzzt"
  601.     eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
  602.     __END__
  603.     foo at - line 2001.
  604.  
  605.     % perl
  606.     eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
  607.     __END__
  608.     foo at foo bar line 200.
  609.  
  610.     % perl
  611.     # line 345 "goop"
  612.     eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
  613.     print $@;
  614.     __END__
  615.     foo at goop line 345.
  616.  
  617. =cut
  618.